;UoM_Project

;T2 measurement using Periodic Refocusing of J evolution by Coherance Transfer (PROJECT) using perfect spin echo
;
;Developed By NMR Group
;Department of Chemistry
;University of Manchester
;United Kingdom
;2019
;
;J.A. Aguilar, M. Nilsson, G. Bodenhausen, G. Morris, Chem. Commun.,2012,48,811-813.

;$CLASS=HighRes
;$DIM=1D
;$TYPE=
;$SUBTYPE=
;$COMMENT=

#include <Avance.incl>
#include <Delay.incl>

"p2=p1*2"
"d11=30m"

"acqt0=0"
baseopt_echo

1 ze
2 d11 pl1:f1

  d1
  p1 ph1

3 d20
  p2 ph2
  d20
  p1 ph3
  d20
  p2 ph2
  d20
  lo to 3 times c

  go=2 ph31
 d11 mc #0 to 2 F1QF(ivc)
exit


ph1=0 2 0 2 1 3 1 3 2 0 2 0 3 1 3 1
ph2=1 1 1 1 0 0 0 0 3 3 3 3 2 2 2 2
ph3=1 1 3 3 0 0 2 2 3 3 1 1 2 2 0 0
ph31=0 2 0 2 1 3 1 3 2 0 2 0 3 1 3 1


;pl1 : f1 channel - power level for pulse (default)
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;d1 : relaxation delay; 1-5 * T1
;d11: delay for disk I/O                             [30 msec]
;d20: fixed echo time to allow elimination of J-mod. effects 
;     d20 should be << 1/J ,but > (50 * P2)       [1-2 msec]
;vc : variable loop counter, taken from vc-list
;NS: 2 * n, total number of scans: NS * TD0
;DS: 2


;define VCLIST

;this pulse program produces a ser-file (PARMOD = 2D)

;vc : vc should contain even numbers to provide 
;     for cancellation of 180 degree pulse errors