;Juan A. Aguilar. Mathias Nilsson. Gareth A. Morris. Manchester. 2011.
;NB development version, subject to change.
;http://nmr.chemistry.manchester.ac.uk
;avance-version (30/11/2011)
;2D homonuclear shift correlation
;phase sensitive
;using gradient pulses for selection
;with multiple quantum filter according to gradient ratio
;constant time version
;$CLASS=HighRes
;$DIM=2D
;$TYPE=
;$SUBTYPE=
;$COMMENT=
#include <Avance.incl>
#include <Delay.incl>
#include <Grad.incl>
"p2=p1*2"
"d13=4u"
"in0=inf1/2"
"in10=in0"
"d0=d25-p16-d16"
"d10=d25-p16-d16"
"DELTA=p16+d16+d13"
1 ze
2 30m 
10m UNBLKGRAD
;;;;;;;;;;;;;;;;;;;;; Pre-filter. Attenuation of rapid pulsing artefacts ;;;;;;;;;;;
p16:gp0
d16
p1*500 ph11
10m
p1*250 ph12
p16:gp0
;;;;;;;;;;;;;;;;;;;;; Pre-filter. Attenuation of rapid pulsing artefacts ;;;;;;;;;;;
d1 BLKGRAD
;;;;;;;;;;;;;;;;;;;;;;;;;;CT ;;;;;;;;;;;;;;;;;;;;;;;;;;
3 p1 ph1
d0 UNBLKGRAD
p16:gp1
d16
p2 ph10  
p16:gp1
d16
d10
;;;;;;;;;;;;;;;;;;;;;;;;;;2Q ;;;;;;;;;;;;;;;;;;;;;;;;;;
  p1 ph2
  DELTA 
  p2 ph4
  p16:gp2
  d16
  d13
;;;;;;;;;;;;;;;;;;;;;;;;;;1Q ;;;;;;;;;;;;;;;;;;;;;;;;;;
  p1 ph3
  DELTA
  p2 ph4
  d13
  p16:gp3
  d16 BLKGRAD
  go=2 ph31
  
30m mc #0 to 2 F1PH(ip1, dd10 & id0)
exit
ph1=1 3
ph2=0 
ph3=1 
ph4=0 
ph10=0 
ph11=0
ph12=1
ph31=0 2
;pl1 : f1 channel - power level for pulse (default)
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p16: homospoil/gradient pulse
;d0 : incremented delay (2D)
;d1 : relaxation delay; 1-5 * T1
;d13: short delay                                    [4 usec]
;d16: delay for homospoil/gradient recovery
;d25: d25*2.0 is the constant time. Make sure that td1/sw1/2 is longer than p16+d16.
;td1: number of experiments
;NS: 1 * n
;FnMODE: TPPI.;use gradient ratio: gp0 : gp1 : gp2 : gp3. 
;                           -75 :  80 : -30 :  60  for a double quantum filter
;                           -75 :  80 : -15 :  45  for a triple quantum filter
: The last two gradients form the n quantum filters. Use 1:2 for DQF, 1:3 for TQF, etc.
; The first gradient, gp0 is used to attenuate rapid pulsing artefacts.
; The second gradient, gp1, is used to clean up the 180 rf pulse of the constant time element.
     
;$Id:  ber 05_d. Exp $