; push1dzs
;
; Zangger-Sterk pure shift sequence
; Uses pulse order: broadband then selective (unpublished)
; J is refocussed at centre of chunk
;
; Ralph Adams, Juan Aguilar, Robert Evans, Mathias Nilsson and Gareth Morris
; University of Manchester
; Release 1.0c (18Oct2011)
; Avance III Version
; 
; Source:
; J.A. Aguilar, S. Faulkner, M. Nilsson and G.A. Morris, Angew. Chem. Int. Ed.; 2010, 49, 3901-3903.
;
; Other relevant papers that could be of use include:
; G.A. Morris, J.A. Aguilar, R. Evans, S. Haiber and M. Nilsson, J. Am. Chem. Soc.; 2010, 132, 12770 - 12772.
; M. Nilsson and G.A. Morris, Chem. Commun.; 2007, 9, 933 - 935.
; 
; Data can be reconstructed using the 'pshift' macro.

;$CLASS=HighRes
;$DIM=2D
;$TYPE=
;$SUBTYPE=
;$COMMENT=

#include <Avance.incl>
#include <Grad.incl>

define delay tauA
define delay tauB
define delay tauC


"in0=inf1/2"   
"p2=p1*2"
"tauA=in0/2-p16-d16-50u"
"tauB=in0-p16-d16-300u"
"tauC=in0/2-p16-d16-350u-(dw*2)-(dw*2*cnst4)-de"

1 ze
2 d1 pl1:f1
3 p1 ph1                 ; 90
  
  d0                     ; Incremented delay

  tauA
  50u UNBLKGRAD
  p16:gp1*0.5            ; CTP, +0.5
  d16
  
  p2 ph2                 ; 180 (H)
  
  tauB 
  p16:gp1*-0.5           ; CTP, -0.5
  d16
  
  300u gron2             ; Slice selection gradient On
  p12:sp2:f1 ph3:r       ; 180 (selective)
  100u groff             ; Slice selection gradient Off
  200u
	
  p16:gp1*-1.0           ; CTP, -1
  d16
  50u BLKGRAD
  tauC						
  d0                     ; incremented delay
	
4 go=2 ph31
  30u
  d1 mc #0 to 2 F1QF(id0)

exit

;Phase Cycling
;ph1	    	; Hard_90 
;ph2		; Hard_180
;ph3		; Selective_180
;ph31		; Receiver

ph1= 0 2 0 2 1 3 1 3 0 2 0 2 1 3 1 3 0 2 0 2 1 3 1 3 0 2 0 2 1 3 1 3 0 2 0 2 1 3 1 3 0 2 0 2 1 3 1 3 0 2 0 2 1 3 1 3 0 2 0 2 1 3 1 3	; Hard_90 
ph2= 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2 3 3 3 3 3 3 3 3 3 3 3 3 3 3 3 3 	; Hard_180
ph3= 0 0 1 1 0 0 1 1 2 2 3 3 2 2 3 3 0 0 1 1 0 0 1 1 2 2 3 3 2 2 3 3 0 0 1 1 0 0 1 1 2 2 3 3 2 2 3 3 0 0 1 1 0 0 1 1 2 2 3 3 2 2 3 3	; Soft_180
ph31=0 2 2 0 1 3 3 1 0 2 2 0 1 3 3 1 2 0 0 2 3 1 1 3 2 0 0 2 3 1 1 3 0 2 2 0 1 3 3 1 0 2 2 0 1 3 3 1 2 0 0 2 3 1 1 3 2 0 0 2 3 1 1 3    ; Receiver

;ph31= ph1 + ph2*2 + ph3*2		; Receiver

;p1: high power 90 pulse width
;p12: selctive 180 pulse width
;p2: high power 180 pulse width
;p16: CTP gradient pulse width
;pl1: f1 channel - power level for pulse (default)
;pl10: 120 dB 

;sp2: selective pulse power level
;spoffs2: selective pulse offset (0 Hz)
;spnam2:  file name for selective pulse

;gpz1: CTP gradient 50-90%
;gpz2: slice selection gradient
;gpnam1: SINE.100

;d0: incremented delay, set initial value to 0 s
;d1: relaxation delay; 1-5 * T1
;d16: gradient stabilisation delay
;td1: number of chunks to acquire

;NS: number of scans
;DS: number of dummy scans
;td1: number of experiments
;cnst4: number of points to drop when collecting FID
;
;FnMODE: QF

; ---Instructions---
; 
;pulse sequence = 90 - 0.5*t1 - tauA - 180H - tauB - 180ZS - tauC - 0.5*t1 - acquire
;
;(1) calibrate 90 degree hard pulse as normal
;(2) calibrate selective pulse using 'stdisp'
;(a) Calculate bandwidth
;this requires required bandwidth(Hz) and required rotation to produce a bandwidth (s)
;(b) Integrate shape
;this requires the bandwidth (s), required rotation and gives a change in power
;
;swh in F2 is an integer multiple of swh in F1
;
;$Id: push1dzs,v 1.0 2011/10/18 Copyright University of Manchester