;psyche_idosy_lock.mf
;
;2D PSYCHE
;Pure Shift Yielded by Chirp Excitation
;modified for internal calculation of RF amplitude of PSYCHE pulse element 
;based on desired flip angle and bandwidth of chirp pulses
;
;Mohammadali Foroozandeh
;University of Manchester
;Avance II+/III Version
;Topspin 3.x
; 
;Data can be reconstructed using a macro available at http://nmr.chemistry.manchester.ac.uk
;
;(1)  Foroozandeh, M.; Adams, R. W.; Meharry, N. J.; Jeannerat, D.; Nilsson, M.; Morris, G. A. Angew. Chem. Int. Ed. 2014, 53, 6990.
;(2)  Foroozandeh, M.; Adams, R. W.; Nilsson, M.; Morris, G. A. J. Am. Chem. Soc. 2014, 136, 11867.
;
;$CLASS=HighRes
;$DIM=2D
;$TYPE=
;$SUBTYPE=
;$COMMENT=

#include <Avance.incl>
#include <Delay.incl>
#include <Grad.incl>
#include <De.incl>

define list<gradient> diff=<Difframp>
define delay tauA
define delay tauB

"p2=p1*2"; 180 and 90 degree pulses
"d11=30m"

;PSYCHE parameters

"in0=inf1/2"
"tauA=in0/2-p16-d16-50u"
"tauB=(dw*2*cnst4)+d16+50u"
"cnst50=(cnst48/360)*sqrt((2*cnst49)/(p40/1000000))"
"p31=1000000.0/(cnst50*4)"
"cnst31= (p31/p1) * (p31/p1)"
"spw40=plw1/cnst31"
"p10=p40"

;DOSY paremeters

"DELTA=d20-tauB-p30-2*d16-2*p40-20u"

aqseq 312

1 ze
2 d11
  50u LOCKH_OFF
  d1 pl1:f1
  50u LOCKH_ON

3 p1 ph1 
  d0
  tauA
  50u UNBLKGRAMP
  p16:gp2 
  d16
  p2 ph2 
  50u
  p16:gp2 
  d16
  tauA
  p30:gp1*diff 
  d16
  10u pl0:f1
  tauB
  ( center (p40:sp40 ph3):f1 (p10:gp10) )
  DELTA
  ( center (p40:sp40 ph3):f1 (p10:gp10) )
  d16
  10u pl1:f1
  p30:gp1*diff 
  d16
  50u BLKGRAMP
  d0
  go=2 ph31
  d11 mc #0 to 2
  F1QF(id0)
  F2QF(rd0, igrad diff)
  50u LOCKH_OFF
exit

ph1= 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0		
ph2= 0 0 0 0 1 1 1 1 2 2 2 2 3 3 3 3		
ph3= 0 1 2 3 0 1 2 3 0 1 2 3 0 1 2 3
ph31=0 2 0 2 2 0 2 0 0 2 0 2 2 0 2 0

;pl0 : zero power (120 dB)
;pl1 : high power (dB) 
;p1  : 90 degree high power pulse
;p16 : duration of CTP gradients (1m)
;p10 : duration of weak gradient during PSYCHE pulse element
;p30 : duration of diffusion encoding gradient
;p40 : duration of double-chirp PSYCHE pulse element
;d0  : incremented delay
;d1  : relaxation delay
;d16 : recovery delay for gradients
;spw40 : RF power of double-chirp PSYCHE pulse element
;spnam40: file name for PSYCHE pulse element
;gpz1: diffusion encoding gradient (100%) 
;gpz2: CTP gradient (77%)
;gpz10: weak gradient during PSYCHE element (3%)
;gpnam1: SINE.100
;gpnam2: SINE.100
;gpnam10: RECT.1
;cnst4: number of drop points
;cnst48: desired flip angle for PSYCHE pulse element (degree) (normally 10-25) 
;cnst49: bandwidth of each chirp in PSYCHE pulse element (Hz) (normally 10000)
;in0 : 1/(2 * SW) = DW
;td1 : number of t1 increments
;MC2 : QF