;ODYSSEUS

;Pulse sequence code for the acquisition of: 1H decoupled, 13C filtered, 19F spectra 

;DEveloped by Methodology NMR Group
;University of Manchester
;Avance II+/III Version

;$CLASS=HighRes
;$DIM=2D
;$TYPE=
;$SUBTYPE=
;$COMMENT=


#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>


"p2=p1*2"
"p4=p3*2"


"d2=1s/(cnst2*2)"
"d11=30m"
"d12=20u"
"d19=p3+d12"
"d0=3u"

"DELTA1=d2-p16-d16-50u"
"DELTA2=d2-p16-d16-50u-2*p3"

"in0=inf1/2"

1 ze
  d11 pl16:f3
2 30m do:f3

  d1 
  d12 pl1:f1 pl2:f2 

	(p1 ph1):f1
	50u UNBLKGRAD
	DELTA1
	p16:gp1
	d16
  (p2 ph2):f1
  (p3 ph4):f2
	p16:gp1
	d16
	DELTA2
	50u BLKGRAD
	(p3 ph5):f2
	d19
	d0
	(center (p2 ph3):f1 (p4 ph6):f2)
	d0
	(p3 ph7):f2  
  d12 pl16:f3
  go=2 ph31 cpd3:f3
  30m do:f3 mc #0 to 2 F1PH(calph(ph7, +90), caldel(d0, +in0))
exit


ph1=0 0 0 0 1 1 1 1 2 2 2 2 3 3 3 3
ph2=0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 
ph3=0 0 0 0 2 2 2 2 0 0 0 0 2 2 2 2 
ph4=0 2 0 2 0 2 0 2 0 2 0 2 0 2 0 2
ph5=0 0 2 2 0 0 2 2 0 0 2 2 0 0 2 2 
ph6=0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0
ph7=0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 
ph31=0 0 0 0 1 1 1 1 2 2 2 2 3 3 3 3 


;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;pl3 : f3 channel - power level for pulse (default)
;pl12: f2 channel - power level for CPD/BB decoupling
;pl16: f3 channel - power level for CPD/BB decoupling
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p3 : f2 channel -  90 degree high power pulse
;p4 : f2 channel - 180 degree high power pulse
;p16: gradient pulse [1 msec] 
;d1 : relaxation delay; 1-5 * T1
;d0	: incremented delay (2D) [3 usec]
;d2	: 1/(2J(FC))

;cnst2: = one bond J(FC)

;ns: 2*n 
;ds: 4

;for z-only gradients:
;gpz1: 35% CTP

;FnMODE: States 

;use gradient files:
;gpnam1: SMSQ10.100