; oneshothsqc
; avance-version (05/05/18)
; 3D DOSY-HSQC
;
; Guilheme Dal Poggetto, Laura Castaņar and Peter Kiraly
; University of Manchester
; <2018>
;
; 2D H-1/X correlation via double inept transfer
;          phase sensitive using Echo/Antiecho-TPPI gradient selection
;         diffusion encoding using Oneshot
;         with decoupling during acquisition
;         using shaped pulses for inversion and refocussing on f2 - channel
;
; For processing data use MAGNATE, available at:
; http://nmr.chemistry.manchester.ac.uk/
;
;$CLASS=HighRes
;$DIM=3D
;$TYPE=
;$SUBTYPE=
;$COMMENT=


#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>


;;;;;;;;;;;;;;;; DOSY parameters ;;;;;;;;;;;;;;;;
define list<gradient> diff=<Difframp>

"cnst14=0.2"
"cnst15=1+cnst14"  ; 1 + alpha
"cnst16=1-cnst14"  ; 1 - alpha

"cnst17=(2*p1+d16)*0.000001"; Dtau %GDP corrected

;Assuming half-sine gradient pulses [most common on Bruker systems]
"cnst18=0.000001*p30*2*0.000001*p30*2*(d20 - (2*0.000001*p30*(5-3*cnst14*cnst14)/16) - (cnst17*(1-cnst14*cnst14)/2) )" ; Dosytimecubed

"DELTA1=d20-4.0*p1-4.0*p30-5.0*d16-p19" ;

;;;;;;;;;;;;;;;; HSQC parameters ;;;;;;;;;;;;;;;;
"d4=1s/(cnst2*4)"

"d0=3u"
"in0=inf1/2"

"DELTA2=d4-p16-larger(p2,p14)/2-de-8u"
"DELTA3=d4-larger(p2,p14)/2"
"DELTA4=d4-larger(p2,p14)/2-p1*2/PI"
"DELTA=p16+d17+p2+d0*2"

"d11=30m+1s/(cnst50)-1s/(cnst50)"
"d11=30m+1s/(cnst51)-1s/(cnst51)"
"d11=30m+1s/(cnst53)-1s/(cnst53)"

"spoff3=0"
"spoff7=0"
"spoff15=0"
"spoal3=0.5"
"spoal7=0.5"
"spoal15=0.5"

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
"d18=2m"
"p2=p1*2"
"p4=2*p3"
"d11=30m"
"acqt0=0"

baseopt_echo
aqseq 312

1 ze
  d11 pl12:f2

2 d11 do:f2 
  1m pl1:f1
  1m pl2:f2
  10u UNBLKGRAD
  p8 ph21
  p8 ph22
  d18 BLKGRAD
  d1
  1m  UNBLKGRAD
  p19:gp2*-1.0				;Spoiler gradient balancing pulse
  d16 

3 (p1 ph1)				; start of ONESHOT		              	
  p30:gp1*diff*cnst16 		 	;1 - alpha
  d16     
  p2 ph8					;First 180
  p30:gp1*-1*diff*cnst15		;1 + alpha
  d16
  p1 ph2					; 2nd 90
  p30:gp1*diff*2*cnst14			;Lock refocusing pulse pulse
  d16
  p19:gp2				;Spoiler gradient balancing pulse
  d16 
  DELTA1
  p30:gp1*diff*2*cnst14 		;Lock refocusing pulse pulse
  d16   
  p1 ph3					; 3rd 90
  p30:gp1*diff*cnst16   			; 1 - alpha
  d16
  p2 ph8		
  p30:gp1*-1*diff*cnst15		;1 + alpha
  d16
  					; end of ONESHOT ;

 					 ; start of HSQC ;
  DELTA3
  4u pl0:f2
  (center (p2 ph8) (p14:sp3 ph9):f2 )
  4u pl2:f2
  DELTA3
  4u
  (p1 ph4) (p3 ph5):f2

  d0 
  (p2 ph7)
  d0

  p16:gp3*EA
  d17
  4u pl0:f2
  (p24:sp7 ph6):f2
  4u pl2:f2
  DELTA
  (ralign (p1 ph8) (p3 ph6):f2 )
  DELTA4 pl0:f2
  (center (p2 ph8) (p14:sp3 ph8):f2 )
  4u
  p16:gp4
  DELTA2 pl12:f2
  4u BLKGRAD
; end of HSQC ;

  go=2 ph31 cpd2:f2
  d11 do:f2 mc #0 to 2 
  F2QF(calgrad(diff))
  F1EA(calgrad(EA), caldel(d0, +in0) & calph(ph5, +180) & calph(ph9, +180) & calph(ph31, +180))
exit
   

ph1=0 0 2 2
ph2=0 0 0 0 0 0 0 0 2 2 2 2 2 2 2 2
ph3=0 0 0 0 2 2 2 2
ph4=1
ph5=0 2
ph6=0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2
ph7=0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2
ph8=0
ph9=0
ph21=0
ph22=1
ph31=0 2 2 0 2 0 0 2 2 0 0 2 0 2 2 0 2 0 0 2 0 2 2 0 0 2 2 0 2 0 0 2 0 2 2 0 2 0 0 2 2 0 0 2 0 2 2 0 2 0 0 2 0 2 2 0 0 2 2 0 2 0 0 2


;pl0 : 0W
;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;pl12: f2 channel - power level for CPD/BB decoupling
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p3 : f2 channel -  90 degree high power pulse
;p4 : f2 channel - 180 degree high power pulse
;p8 : f1 channel - spherical randomization high power pulse		[1.5 msec]
;p14: f2 channel - 180 degree shaped pulse for inversion
;p24: f2 channel - 180 degree shaped pulse for refocussing
;p16: gradient encode/decode (HSQC)
;p19:	gradient pulse 2 (spoil gradient)					[1.2 msec]
;p30:	gradient pulse (little DELTA*0.5)
;spnam3: f2 channel - shaped pulse for refocussing
;spnam7: f2 channel - shaped pulse for inversion
;spnam15: f2 channel - shaped pulse cpd2
;d0 : incremented delay (2D)                         				[3 usec]
;d1 : relaxation delay; 1-5 * T1
;d4 : 1/(4J)XH
;d11: delay for disk I/O                             					[30 msec]
;d16: delay for gradient recovery (Oneshot)
;d17: delay for gradient recovery (HSQC)
;d18: delay for gradient recovery (Spherical randomization)    [2 msec]
;d20: diffusion encoding period (big DELTA)
;cnst2: = J(XH)
;cnst50: sweep-width [kHz]
;cnst51: duration of the low-level W40 pulse [us]
;cnst53: adiabaticity factor of the low-level W40 pulse [Q=2.0]
;inf1: 1/SW(X) = 2 * DW(X)
;in0: 1/(2 * SW(X)) = DW(X)
;nd0: 2

;ns: 2 * n
;ds: >= 16
;td1: number of experiments HSQC
;td2: number of experiments Oneshot
;FnMODE(F1): echo-antiecho
;FnMODE(F2): QF

;cpd2: decoupling according to sequence defined by cpdprg2
;pcpd2: f2 channel - 90 degree pulse for decoupling sequence

;use gradient ratio:	gp 3 : gp 4
;			  80 : 20.1    for C-13
;			  80 :  8.1    for N-15

;for z-only gradients:
;gpz1: 100%
;gpz2: 67%
;gpz3: 80%
;gpz4: 20.1% for C-13, 8.1% for N-15

;use gradient files:   
;gpnam1: SINE.100
;gpnam2: SINE.100
;gpnam3: SMSQ10.100
;gpnam4: SMSQ10.100

; Instructions for wavemaker:
;sp15(pcpd2,pl12):wvm:kp_W40:f2 cawurst-40(cnst50 kHz, cnst51 us; Q=cnst53 SUCYC=[p5]m4) ss=0.5us;