; Selective 1D CLIP-COSY experiment using GEMSTONE for ultra-selective excitation.
;
; For Bruker DRX spectrometers using TopSpin 1.3. Manual generation of waveforms using Bruker shape tool.
;
; Daniel Taylor
; Manchester NMR Methodology Group
; Department of Chemistry
; University of Manchester
;
; References:
; [1] D. A. Taylor, P. Kiraly, P. Bowyer, M. Nilsson, L. Castanar, G. A. Morris, and R. W. Adams,
;     Chem. Commun., 2023, in press.
;	  
; [2] P. Kiraly, M. Nilsson, G. A. Morris, and R. W. Adams, Chem. Commun., 2021, 57, 2308-2371.
;  
; [3] P. Kiraly, N. Kern, M. Plesniak, M. Nilsson, D. J. Procter, G. A. Morris, and R. W. Adams,
;     Angew. Chem. Int. Ed., 2021, 60, 666-669.
;	  
; 20/04/2023

;$CLASS=HighRes
;$DIM=1D
;$TYPE=
;$SUBTYPE=
;$COMMENT=

#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>

"d11=30m"

"p2=p1*2"

"acqt0=0.0"

1 ze
2 30m

  50u BLKGRAMP	
  50u LOCKH_OFF 
  d1 pl1:f1
  50u LOCKH_ON 
  50u UNBLKGRAMP

  /* Hard 90deg pulse */
  (p1 ph1):f1

  /* Low to high adiabatic sweep */
  d16
  10u gron11
  (p24:sp24 ph2):f1
  10u groff
  d16

  /* Selective 180 */
  p16:gp1
  d16
  p12:sp12:f1 ph3:r
  p16:gp1
  d16 pl1:f1

  /* High to low adiabatic sweep */
  d16
  10u gron12
  (p25:sp25 ph4):f1
  10u groff
  d16 pl1:f1

  /* CLIP COSY */
  (p1 ph5):f1
	
  10u gron20
  (p32:sp29 ph6):f1
  20u groff
  d16 pl1:f1

  (p1 ph7):f1
  d4
  (p2 ph8):f1
  d4
  (p1 ph9):f1
  d4
  (p2 ph10):f1
  d4
  (p1 ph11):f1

  10u gron21
  (p33:sp30 ph12):f1
  20u groff
  d16 pl1:f1

  p16:gp2
  d16
  (p1 ph13):f1

  /* Acquisition */
  go=2 ph31
  30m mc #0 to 2 F0(zd)

  50u BLKGRAD

exit

 ph1 = 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2 2
 ph2 = 0
 ph3 = 0 0 0 0 1 1 1 1 2 2 2 2 3 3 3 3
 ph4 = 0
 ph5 = 0 0 2 2
 ph6 = 0
 ph7 = 0
 ph8 = 1
 ph9 = 1
 ph10 = 3
 ph11 = 0
 ph12 = 0
 ph13 = 0 2
 ph31 = 0 2 2 0 2 0 0 2 0 2 2 0 2 0 0 2 2 0 0 2 0 2 2 0 2 0 0 2 0 2 2 0

;pl1 : f1 channel - power level for pulse (default)
;sp12: f1 channel - shaped pulse, rSNOB
;sp24: f1 channel - shaped pulse (adiabatic), GEMSTONE L2H sweep
;sp25: f1 channel - shaped pulse (adiabatic), GEMSTONE H2L sweep
;sp29: f1 channel - shaped pulse (adiabatic), zero-quantum suppression
;sp30: f1 channel - shaped pulse (adiabatic), zero-quantum suppression

;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p12: f1 channel - 180 degree shaped pulse
;p16: homospoil/gradient pulse									[1 msec]
;p24: f1 channel - adiabatic pulse, GEMSTONE L2H sweep
;p25: f1 channel - adiabatic pulse, GEMSTONE H2L sweep
;p32: f1 channel - adiabatic pulse, zero-quantum suppression    [10 msec]
;p33: f1 channel - adiabatic pulse, zero-quantum suppression    [30 msec]

;d1 : relaxation delay; 1-5 * T1
;d4 : COSY mixing time; 1/(4*J(HH))
;d16: delay for homospoil/gradient recovery

;ns: 2 * n, total number of scans: NS * TD0
;ds: 4

;phcor 2 : phasedifference between power levels sp1 and pl1

;for z-only gradients:
;gpz1: 15 %
;gpz2: -2 %
;gpz11: +0.5 %
;gpz12: -0.5 %

;use gradient files:   
;gpnam1: SMSQ10.100
;gpnam2: SMSQ10.100

; For sweepwidth of adiabatic shape and adjusting gpz0
; see supplementary material of M.J. Thrippleton & J. Keeler,
; Angew. Chem. Int. Ed. 42, 3938-3941 (2003)
; use pulseprogram zs_setup

                                          ;preprocessor-flags-start
;CALC_SPOFFS: automatically calcuate spoffs for selective pulses
;             start experiment with option -DCALC_SPOFFS (eda: ZGOPTNS)
;FLAG_BLK: for BLKGRAD before d1 rather than go
;             option -DFLAG_BLK: (eda: ZGOPTNS)
                                          ;preprocessor-flags-end

;$Id: dat_GEMSTONE_CLIPCOSY,v3, 2023/04/20 00:00:00 dat Exp $