;DISPEL (four stage)
;	
;	Pulse sequence for the suppression of one-bond 13C satellites in 1H spectra
;	(with cw presaturation)
;
;	Developed by:
;	NMR Methodolgy Group
;	University of Manchester
;
;Topspin 4.x
;
;$CLASS=HighRes
;$DIM=1D
;$TYPE=
;$SUBTYPE=
;$COMMENT=


#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>

"acqt0=-p1*2/3.1416"

"p2=p1*2"

"d2=4050u"
"d3=3200u"
"d4=1100u"
"d5=3950u"
"d6=1560u"

"d13=50u"

"DELTA1=d3-d13-(p3/2)-d16-p16"
"DELTA2=d2-d3-(p3/2)-(p2/2)"
"DELTA3=d2-d3+d4-(p3/2)-(p2/2)-p16-d16"
"DELTA4=d3-d4-(p3/2)-(p1/2)"
"DELTA5=d5-p16-d16-(p1/2)-(p3/2)"
"DELTA6=d2-d5-(p3/2)-(p2/2)"
"DELTA7=d2-d5+d6-(p2/2)-(p3/2)-p16-d16"
"DELTA8=d5-d6-(p3/2)"

1 ze
2 30m
  20u BLKGRAD
  30u pl9:f1
  d1 
  2s cw:f1 ph29
  4u do:f1
  30u 
  d13 pl1:f1 pl2:f2 
3 (p1 ph1):f1
	d13 UNBLKGRAD
  DELTA1
	p16:gp1
	d16
	(p3 ph5):f2
  DELTA2 
	(p2 ph2):f1 
	p16:gp1
	d16
  DELTA3
	(p3 ph6):f2
  DELTA4
  (p1 ph3):f1 
  DELTA5
	p16:gp2
	d16
  (p3 ph7):f2 
	DELTA6
	(p2 ph4):f1 
	p16:gp2
	d16	
  DELTA7
	(p3 ph8):f2 
  DELTA8

	(p1 ph9):f1   ;z-filter
  10u gron0 pl0:f1
 	(p32:sp29 ph10):f1
  20u groff
	d17 pl1:f1
	p18:gp3
  d17
	(p1 ph11):f1

  go=2 ph31 
  30m mc #0 to 2 F0(zd)
  20u BLKGRAD
exit
   

ph1=0 2 
ph2=0 0 0 0 0 0 0 0 1 1 1 1 1 1 1 1 2 2 2 2 2 2 2 2 3 3 3 3 3 3 3 3
ph3=1 
ph4=2 2 3 3 0 0 1 1 
ph5=0 2  
ph6=0 0 2 2
ph7=0 0 0 0 2 2 2 2
ph8=0 0 0 0 0 0 0 0 2 2 2 2 2 2 2 2 
ph9=0 
ph10=0 
ph11=0
ph29=0
ph31=0 2 2 0 0 2 2 0 2 0 0 2 2 0 0 2
  
 

;POWER LEVEL
;pl0 : 0W
;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;pl9 : f1 channel - power level for presaturation
;sp29: f1 channel - power level of adiabatic pulse of ZQF element


;PULSE SHAPE
;spnam29 : f1 channel - file name for the adiabatic shaped pulse using in ZQF   [Crp60,20,20.10]


;PULSE DURATION
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p3 : f2 channel -  90 degree high power pulse
;p32: f1 channel - 180 degree shaped pulse (adiabatic)    [20 msec]


;GRADIENT DURATION
;p16: duration of CTP gradients                      [1 msec]
;p18: homospoil gradient 							 [1 msec]

;DELAY
;d1 : relaxation delay; 1-5 * T1
;d13: delay for UNBLKGRAD/BLKGRAD
;d16: delay for gradient recovery			 [500usec]
;d17: delay for gradient recovery during ZQF [20msec]


;GRADIENT SHAPE
;gpnam1 : SMSQ10.100
;gpnam2 : SMSQ10.100
;gpnam3 : SMSQ10.100

;GRADIENT STRENGTH
;gpz0  : ZQF gradient 					  	[3%]
;gpz1  : CTP gradient 						[43%]
;gpz2  : CTP gradient				 		[37%]
;gpz3  : homospoil gradient      			[31%]

;OTHER
;ns: 1 * n, total number of scans: NS * TD0
;ds: 2